tree_2.grammar

source: package_decl {import_decl} {using_decl} {decl};

// Package
package_decl: $var_id ":" [$package] ":" $package "(" $string ")" [";"];

// Import
import_decl: $var_id ":" [$import] ":" $import "(" $string ")" [";"];

// Using
using_decl: $any_ids ":" [$using] ":" $using "(" $var_id ")" [";"];

// Declaration
decl: var_decl | any_type_decl | templ_decl;

// Variable
var_decl: ( $var_id ":" [$type_id] ":" $any_lit
          | $var_id ":" $type_id
		  )
		  [";"];

// Type
any_type_decl: derived_type_decl | enum_decl | record_decl | union_decl;

// Derived type
derived_type_decl: type_ids ":" [$type] ":" $type "(" $type_id ")" [";"];

// Record
record_decl: type_ids ":" [$type] ":" $record "{" [var_decl {";" var_decl}] "}" [";"];

// Enum
enum_decl: type_ids ":" [$type] ":" $enum "{" [$var_id {";" $var_id}] "}" [";"];

// Union
union_decl: type_ids ":" [$type] ":" $union "{" [$type_id {"," $type_id}] "}" [";"];

// Template
templ_decl: $var_id ":" [$templ] ":" $templ "(" $type_id ")" "{" {$elements} "}" [";"];

// Utils
any_ids: $any_id {"," $any_id};
type_ids: $type_id {"," $type_id};