fix Hunk header display

Author: myfreess

diff/README.mbt.md

@@ -74,8 +74,9 @@ test "patience diff keeps unique anchors in place" {
 ## Group Into Hunks And Render
 
 `group` splits the edit script into `Hunk[T]` values, keeping `radius` lines
-of surrounding context (default 3). Each `Hunk[T]` implements `Show`, so you
-can print it directly as unified-diff output.
+of surrounding context (default 3). `radius` must be non-negative, and
+`radius=0` emits hunks without surrounding context. Each `Hunk[T]` implements
+`Show`, so you can print it directly as unified-diff output.
 
 ```mbt check
 ///|

diff/diff_test.mbt

@@ -175,6 +175,39 @@ test "delete then insert to hunks" {
   )
 }
 
+///|
+test "delete then insert to hunks without context" {
+  let old = ["fn main() {", "  println(\"foo\")", "}"][:]
+  let new = ["fn main() {", "  println(\"bar\")", "}"][:]
+  let d = @diff.Diff(old~, new~)
+  let patience = @diff.Diff(old~, new~, patience=true)
+  inspect(
+    hunks_to_string(d.group(radius=0)),
+    content=(
+      #|@@ -2 +2 @@
+      #|-  println("foo")
+      #|+  println("bar")
+      #|
+    ),
+  )
+  inspect(
+    hunks_to_string(patience.group(radius=0)),
+    content=(
+      #|@@ -2 +2 @@
+      #|-  println("foo")
+      #|+  println("bar")
+      #|
+    ),
+  )
+}
+
+///|
+test "panic group with negative radius" {
+  let old = ["fn main() {", "}"][:]
+  let new = old
+  ignore(@diff.Diff(old~, new~).group(radius=-1))
+}
+
 ///|
 test "large text to hunks" {
   let old = [

diff/edit.mbt

@@ -88,6 +88,7 @@ fn[T] group_edits(
   old~ : ArrayView[T],
   new~ : ArrayView[T],
 ) -> Array[Hunk[T]] {
+  guard radius >= 0 else { abort("radius must be non-negative") }
   if edits.is_empty() {
     return []
   }

diff/edit_wbtest.mbt

@@ -59,3 +59,14 @@ test "range display for single and empty span" {
     content="@@ -4,0 +3 @@",
   )
 }
+
+///|
+test "range display spans replacement ending with insert" {
+  inspect(
+    HunkHeader::new([
+      Delete(old_index=1, new_index=1, old_len=1),
+      Insert(old_index=1, new_index=1, new_len=1),
+    ]).to_string(),
+    content="@@ -2 +2 @@",
+  )
+}

diff/hunk.mbt

@@ -38,13 +38,31 @@ priv struct HunkHeader(Range, Range)
 ///|
 /// Creates a hunk header from a (non empty) array of edit
 fn HunkHeader::new(edits : ArrayView[Edit]) -> Self {
-  let first = edits[0]
-  let last = edits[edits.length() - 1]
-  let old_start = first.old_range().0
-  let new_start = first.new_range().0
-  let old_end = last.old_range().1
-  let new_end = last.new_range().1
-  HunkHeader(Range(old_start, old_end), Range(new_start, new_end))
+  let (first_old_start, first_old_end) = edits[0].old_range()
+  let (first_new_start, first_new_end) = edits[0].new_range()
+  let mut old_end = first_old_end
+  let mut new_end = first_new_end
+  let mut found_old_end = false
+  let mut found_new_end = false
+  let mut i = edits.length()
+  while i > 0 {
+    i -= 1
+    let edit = edits[i]
+    let (edit_old_start, edit_old_end) = edit.old_range()
+    let (edit_new_start, edit_new_end) = edit.new_range()
+    if !found_old_end && edit_old_start != edit_old_end {
+      old_end = edit_old_end
+      found_old_end = true
+    }
+    if !found_new_end && edit_new_start != edit_new_end {
+      new_end = edit_new_end
+      found_new_end = true
+    }
+    if found_old_end && found_new_end {
+      break
+    }
+  }
+  HunkHeader(Range(first_old_start, old_end), Range(first_new_start, new_end))
 }
 
 ///|