Hypr-DarkWindow/flake.nix at main · micha4w/Hypr-DarkWindow · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
{
  inputs = {
    hyprland.url = "github:hyprwm/Hyprland";

    nix-filter.url = "github:numtide/nix-filter";
  };

  outputs =
    {
      self,
      hyprland,
      nix-filter,
      ...
    }:
    let
      inherit (hyprland.inputs) nixpkgs;
      forHyprlandSystems =
        fn:
        nixpkgs.lib.genAttrs (builtins.attrNames hyprland.packages) (
          system: fn system nixpkgs.legacyPackages.${system}
        );
    in
    {
      packages = forHyprlandSystems (
        system: pkgs:
        let
          hyprlandPackage = hyprland.packages.${system}.hyprland;
        in
        rec {
          Hypr-DarkWindow = pkgs.gcc14Stdenv.mkDerivation {
            pname = "Hypr-DarkWindow";
            version = "5.5.0";
            src = nix-filter.lib {
              root = ./.;
              include = [
                "src"
                ./Makefile
              ];
            };

            nativeBuildInputs = with pkgs; [ pkg-config ];
            buildInputs = [ hyprlandPackage.dev ] ++ hyprlandPackage.buildInputs;

            installPhase = ''
              mkdir -p $out/lib
              install ./out/hypr-darkwindow.so $out/lib/libHypr-DarkWindow.so
            '';

            meta = with pkgs.lib; {
              homepage = "https://github.com/micha4w/Hypr-DarkWindow";
              description = "Apply custom shaders to any Window!";
              license = licenses.mit;
              platforms = platforms.linux;
            };
          };

          default = Hypr-DarkWindow;
        }
      );

      devShells = forHyprlandSystems (
        system: pkgs: {
          default = pkgs.mkShell {
            name = "Hypr-DarkWindow";
            hardeningDisable = [ "fortify" ];

            nativeBuildInputs = with pkgs; [
              clang-tools
              jq
              chromium
            ];

            inputsFrom = [ self.packages.${system}.Hypr-DarkWindow ];
          };
        }
      );
    };
}