CMakeLists.txt

cmake_minimum_required(VERSION 3.16)

project(serialfox_c VERSION 0.2.0 LANGUAGES C)

set(CMAKE_C_STANDARD 11)
set(CMAKE_C_STANDARD_REQUIRED ON)
set(CMAKE_C_EXTENSIONS OFF)

# Build a 4-part version: major.minor.patch.revision.
# Revision uses UTC cumulative days since 1970-01-01.
string(TIMESTAMP SERIALFOX_BUILD_EPOCH_SECONDS "%s" UTC)
math(EXPR SERIALFOX_VERSION_REVISION "${SERIALFOX_BUILD_EPOCH_SECONDS} / 86400")
set(SERIALFOX_VERSION_4 "${PROJECT_VERSION_MAJOR}.${PROJECT_VERSION_MINOR}.${PROJECT_VERSION_PATCH}.${SERIALFOX_VERSION_REVISION}")
set(SERIALFOX_VERSION_COMMA "${PROJECT_VERSION_MAJOR},${PROJECT_VERSION_MINOR},${PROJECT_VERSION_PATCH},${SERIALFOX_VERSION_REVISION}")

if (WIN32)
    # Windows EXE metadata source of truth 2(edit these values in CMakeLists.txt).
    set(SERIALFOX_COMPANY_NAME "XUWH")
    set(SERIALFOX_FILE_DESCRIPTION "SerialFox C Serial Tool")
    set(SERIALFOX_INTERNAL_NAME "serialfox.exe")
    set(SERIALFOX_ORIGINAL_FILENAME "serialfox.exe")
    set(SERIALFOX_PRODUCT_NAME "SerialFox Serial Tool")
    set(SERIALFOX_LEGAL_COPYRIGHT "Copyright (C) 2026 XUWH")

    configure_file(
        ${CMAKE_CURRENT_SOURCE_DIR}/src/serialfox_version.rc.in
        ${CMAKE_CURRENT_BINARY_DIR}/serialfox_version.rc
        @ONLY
    )
endif()

add_executable(serialfox
    src/main.c
    src/app_config.c
    src/hex_codec.c
    src/checksum.c
    src/display_log.c
    src/serial_posix.c
    src/serial_win.c
)

if (WIN32)
    target_sources(serialfox PRIVATE ${CMAKE_CURRENT_BINARY_DIR}/serialfox_version.rc)
endif()

target_include_directories(serialfox PRIVATE include)
target_compile_definitions(serialfox PRIVATE SERIALFOX_VERSION_STR="${SERIALFOX_VERSION_4}")

if (WIN32)
    target_compile_definitions(serialfox PRIVATE _CRT_SECURE_NO_WARNINGS)
else()
    find_package(Threads REQUIRED)
    target_link_libraries(serialfox PRIVATE Threads::Threads)
endif()