fair-er/example_query.sparql at master · fairagro/fair-er · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
# This SPARQL query retrieves the titles and DOIs of datasets, where the DOI is extracted from the access URL of the distribution.

PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX dcat: <http://www.w3.org/ns/dcat#>

SELECT ?title ?doi
WHERE {
  ?dataset a dcat:Dataset ;
           dcterms:title ?title ;
           dcat:distribution ?distribution .
  ?distribution dcat:accessURL ?url .
  BIND(STRAFTER(STR(?url), "https://doi.org/") AS ?doi)
}


# This SPARQL query retrieves the URIs of all metrics and their scores for a specific distribution
# identified by a DOI contained within the distribution URI.

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dqv: <http://www.w3.org/ns/dqv#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX dcat: <http://www.w3.org/ns/dcat#>

SELECT ?metric ?score
WHERE {
  ?distribution a dcat:Distribution .
  FILTER(CONTAINS(STR(?distribution), "10.20387-bonares-tdgx-339v"))
  ?distribution dqv:hasQualityMeasurement ?measurement .
  ?measurement dqv:isMeasurementOf ?metric .
  ?measurement dqv:value ?score .
  ?metric rdf:type dqv:Metric .
}


# This SPARQL query retrieves the URIs of metrics with a score of 0.0 for a specific distribution
# identified by a DOI contained within the distribution URI.

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dqv: <http://www.w3.org/ns/dqv#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX dcat: <http://www.w3.org/ns/dcat#>

SELECT ?metric
WHERE {
  ?distribution a dcat:Distribution .
  FILTER(CONTAINS(STR(?distribution), "10.20387-bonares-tdgx-339v"))
  ?distribution dqv:hasQualityMeasurement ?measurement .
  ?measurement dqv:value "0.0"^^xsd:float .
  ?measurement dqv:isMeasurementOf ?metric .
  ?metric rdf:type dqv:Metric .
}