make-binutils

#!/bin/zsh

if [[ $# -ne 3 ]]; then
    echo "Usage: $0 PACKAGE_VERSION TARGETED_HOST CHECK"
    exit 2
fi

name=binutils


# Use static libraries as much as possible, because the toolchain gets
# tricky otherwise. We will build our static libraries with
# position-independent code.
static_libraries=`mktemp -d`
echo 'GROUP ( /usr/local/lib/libzstd.a )' > ${static_libraries}/libzstd.so || exit 1

export LIBRARY_PATH=${static_libraries}:/usr/local/lib

environment_variables=( )
configure_arguments=(
    --prefix=/usr/local
    --libdir=/usr/local/lib
    --with-native-system-header-dir=/usr/local/include

    --enable-default-pie
    --disable-multilib
    --disable-nls
    --disable-canonical-system-headers
    --enable-year2038
    --enable-lto
    --enable-host-shared
    --enable-{gcov,gprof,gprofng}
    --enable-threads
    --disable-werror
    --enable-new-dtags
    --enable-install-libiberty
    --with-zstd-include=/usr/local
    --with-zstd-lib=${static_libraries}
    --without-{target-,}system-zlib
)

source shared/basic.zsh

#
# Remove temporary directories from .la files.
#
find "${abs_destdir}" -name '*.la' |
    xargs sed -i -E "s:-L${static_libraries}::g" \
        || ${bail_out} 

#
# Modify linker scripts. Rid them of library directories outside the
# /usr/local.
#
sed -i -E 's:SEARCH_DIR\("(/usr)?/lib[^[:space:]]*"\);::g' \
    "${abs_destdir}"/usr/local/*/lib/ldscripts/* || ${bail_out}

#
# If necessary, move libiberty.a
#
# (Apparently, however, setting libdir in config.site works to put
# libiberty.a in the correct place.)
#
if [[ -e "${abs_destdir}"/usr/local/lib64/libiberty.a ]]; then
    mv "${abs_destdir}"/usr/local/lib{64,}/libiberty.a || ${bail_out}
    rmdir "${abs_destdir}"/usr/local/lib64 || ${bail_out}
fi

#
# Remake the tarball.
#
make_package "${bin_tarball}" "${abs_destdir}" || ${bail_out}

rm -R -f ${static_libraries}