Webhook/build.gradle.kts at ver/2.0.0 · Yive/Webhook · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar

plugins {
  java
  application
  id("com.gradleup.shadow") version "9.4.1"
}

group = "dev.yive"
version = "2.1.3"

repositories {
  mavenCentral()
}

val vertxVersion = "5.0.12"

val mainVerticleName = "dev.yive.webhook.MainVerticle"
val launcherClassName = "io.vertx.launcher.application.VertxApplication"

application {
  mainClass.set(launcherClassName)
}

dependencies {
  implementation(platform("io.vertx:vertx-stack-depchain:$vertxVersion"))
  implementation("io.vertx:vertx-launcher-application")
  implementation("io.vertx:vertx-web-client")
  implementation("io.vertx:vertx-web")
  implementation("io.vertx:vertx-config")
  implementation("io.vertx:vertx-config-yaml")
  implementation("com.jakewharton.fliptables:fliptables:1.1.1")
}

java {
  sourceCompatibility = JavaVersion.VERSION_21
  targetCompatibility = JavaVersion.VERSION_21
}

tasks.withType<ShadowJar> {
  archiveFileName.set("webhook.jar")
  archiveClassifier.set("")
  manifest {
    attributes(mapOf("Main-Verticle" to mainVerticleName, "Implementation-Version" to version))
  }

  // Duplicate strategy must be set to INCLUDE due to the fact that EXCLUDE
  // breaks the config processors resulting in only yaml being the only supported format.
  duplicatesStrategy = DuplicatesStrategy.INCLUDE

  mergeServiceFiles()
}

tasks.withType<JavaExec> {
  args = listOf(mainVerticleName)
}