CMakeLists.txt

cmake_minimum_required(VERSION 3.13)

set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)

option(ENABLE_DEBUG "Build with debug features" OFF)
option(ENABLE_TIMING "Build with timing features" OFF)
option(DRY_RUN "Skip patching game files" OFF)
option(LOGIC_TESTS "Logic tests will be run" OFF)
option(QT_GUI "Build with Qt GUI" OFF)
option(EMBED_DATA "Embed data in Qt app" OFF)

# Versioning
if(DEFINED RELEASE_TAG)
  # Use the new tag we're creating for this release (passed in workflow)
  set(GIT_TAG "${RELEASE_TAG}")

  # Also use the seed key to change item placement when a spoiler log isn't generated
  set(SEED_KEY "$ENV{SEED_KEY}")
else()
  # Get previous tag and commit hash
  find_package(Git REQUIRED)
  execute_process(COMMAND "${GIT_EXECUTABLE}" describe --tags --always --dirty --broken
    WORKING_DIRECTORY "${CMAKE_SOURCE_DIR}"
    OUTPUT_VARIABLE GIT_TAG
    ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE
  )
endif()
string(REGEX MATCH "^([0-9]+)\\.([0-9]+)\\.([0-9]+)(-([0-9]+))?(-g([0-9a-f]+))?(-([a-z]+))?" VERSION_MATCH "${GIT_TAG}")
if(VERSION_MATCH)
  set(PROJECT_VERSION "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}.${CMAKE_MATCH_3}")
  if(${CMAKE_MATCH_5})
    string(APPEND PROJECT_VERSION ".${CMAKE_MATCH_5}")
  endif()
else()
  set(PROJECT_VERSION "0.0.0.0")
endif()
configure_file(version.hpp.in version.hpp @ONLY)
configure_file(keys/keys.hpp.in keys/keys.hpp @ONLY)

project(wwhd_rando VERSION ${PROJECT_VERSION} LANGUAGES C CXX)
add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/utf-8>")

if(DEFINED DEVKITPRO)
  add_compile_definitions(DEVKITPRO)
  add_compile_options(-Ofast -mcpu=750 -meabi -mhard-float -ffunction-sections -flto -Wall)
  add_link_options(-flto -fno-fat-lto-objects)
endif()

if(ENABLE_DEBUG)
  message("Debugging is ON")

  add_compile_options(-g)
  add_compile_definitions(ENABLE_DEBUG)
endif()

if(ENABLE_TIMING)
  message("Some events will be timed")

  add_compile_definitions(ENABLE_TIMING)
endif()

if(DRY_RUN)
  message("Game patching will be skipped")

  add_compile_definitions(DRY_RUN)
endif()

if(LOGIC_TESTS)
  message("Configuring for Logic Tests")

  add_compile_definitions(LOGIC_TESTS)

  if(TEST_COUNT)
    message("Test Count: " ${TEST_COUNT})
    add_compile_definitions(TEST_COUNT=${TEST_COUNT})
  endif()
endif()

# Path strings for logging
string(LENGTH "${CMAKE_SOURCE_DIR}/" SOURCE_PATH_SIZE)
add_compile_definitions(SOURCE_PATH_SIZE=${SOURCE_PATH_SIZE})

# Put data files together for easier manipulation
file(COPY "asm/custom_symbols.yaml" DESTINATION "${CMAKE_BINARY_DIR}/data/asm")                    # Custom symbols for inserted code
file(COPY "asm/patch_diffs" DESTINATION "${CMAKE_BINARY_DIR}/data/asm")                            # Diffs for precompiled ASM patches
file(COPY "assets" DESTINATION "${CMAKE_BINARY_DIR}/data")                                         # Assets for the patcher
file(COPY "logic/data/" DESTINATION "${CMAKE_BINARY_DIR}/data/logic" REGEX "^.*example.*$" EXCLUDE) # World, macros, and location info
file(COPY "customizer/data/" DESTINATION "${CMAKE_BINARY_DIR}/data/customizer")                     # Default model info

if(QT_GUI)
  message("Building with Qt GUI")

  find_package(QT NAMES Qt6 Qt5 REQUIRED COMPONENTS Widgets)
  find_package(Qt${QT_VERSION_MAJOR} REQUIRED COMPONENTS Widgets)

  add_compile_definitions(QT_GUI)

  # Set Icon on Mac (has to be done out here)
  set(MACOSX_BUNDLE_ICON_FILE "app.icns")
  set(app_icon_macos "${CMAKE_CURRENT_SOURCE_DIR}/gui/desktop/app.icns")
  set_source_files_properties(${app_icon_macos} PROPERTIES MACOSX_PACKAGE_LOCATION "Resources")

  if(${QT_VERSION_MAJOR} GREATER_EQUAL 6)
    qt_add_executable(wwhd_rando MACOSX_BUNDLE main.cpp ${app_icon_macos})
  else()
    add_executable(wwhd_rando main.cpp)
  endif()

  add_subdirectory("gui/desktop")
else()
  add_executable(wwhd_rando main.cpp)
endif()

target_sources(wwhd_rando PRIVATE "randomizer.cpp" "options.cpp" "tweaks.cpp" "text_replacements.cpp")
add_subdirectory("libs")
add_subdirectory("utility")
add_subdirectory("command")
add_subdirectory("filetypes")
add_subdirectory("seedgen")
add_subdirectory("logic")
add_subdirectory("customizer")

target_include_directories(wwhd_rando PRIVATE ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR})

if(DEFINED DEVKITPRO)
  # Some code specific to Wii U
  add_subdirectory("platform")
  add_subdirectory("nuspack")
  add_subdirectory("gui/wiiu")

  # Use libmocha for filesystem access
  find_library(LIBMOCHA mocha REQUIRED HINTS "${DEVKITPRO}/wut/usr/lib")
  target_include_directories(wwhd_rando PRIVATE "${DEVKITPRO}/wut/usr/include")
  target_link_libraries(wwhd_rando PRIVATE "${LIBMOCHA}")
  
  wut_create_rpx(wwhd_rando)
  wut_create_wuhb(wwhd_rando
    NAME       "The Legend of Zelda: The Wind Waker HD Randomizer"

    CONTENT    "${CMAKE_BINARY_DIR}/data"
    SHORTNAME  "TWWHD Randomizer"
    AUTHOR     "SuperDude88, csunday95, gymnast86"
    ICON       "${CMAKE_SOURCE_DIR}/platform/Icon.png"
    #TVSPLASH   "${CMAKE_SOURCE_DIR}/platform/Splash.png"
    #DRCSPLASH  "${CMAKE_SOURCE_DIR}/platform/Splash.png"
  )
else()
  find_package(Threads REQUIRED)
  target_link_libraries(wwhd_rando PRIVATE Threads::Threads)
endif()