lambxekutor/flake.nix at main · Shapur1234/lambxekutor · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
{
  description = "Lambda executor";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    crane.url = "github:ipetkov/crane";
    flake-utils.url = "github:numtide/flake-utils";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };


  outputs = { self, nixpkgs, crane, flake-utils, rust-overlay, ... }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [ (import rust-overlay) ];
        };

        inherit (pkgs) lib;

        rustToolchain = pkgs.rust-bin.selectLatestNightlyWith (toolchain: toolchain.default.override {
          extensions = [ "rust-src" ];
        });

        craneLib = ((crane.mkLib pkgs).overrideToolchain rustToolchain);

        src = lib.cleanSourceWith {
          src = ./.;
          filter = path: type: (craneLib.filterCargoSources path type);
        };
        cliArgs = {
          inherit src;
          strictDeps = true;
          buildInputs = [ ];

          pname = "lambxekutor_cli";
          cargoExtraArgs = ''--package=lambxekutor_cli'';
        };

        cliArtifacts = craneLib.buildDepsOnly cliArgs;
        cliCrate = craneLib.buildPackage (
          cliArgs // {
            cargoArtifacts = cliArtifacts;
          }
        );
      in
      {
        checks = {
          lambxekutorCrate = cliCrate;
          lambxekutorCliFmt = craneLib.cargoFmt cliArgs;
          lambxekutorCliClippy = {
            inherit src;
            cargoArtifacts = cliArtifacts;

            cargoClippyExtraArgs = "-- --deny warnings";
          };
        };

        packages.default = cliCrate;

        apps.default = flake-utils.lib.mkApp {
          drv = cliCrate;
        };

        devShells.default = craneLib.devShell {
          checks = self.checks.${system};

          packages = with pkgs; [
            rustToolchain
            rust-analyzer

            cargo-flamegraph
            cargo-outdated
          ];
        };
      }
    );
}