Add UTXO loading from the PSBT

Author: bbrtj

lib/Bitcoin/Crypto/PSBT.pm

@@ -8,7 +8,7 @@ use Types::Common -sigs;
 use List::Util qw(any);
 use Scalar::Util qw(blessed);
 
-use Bitcoin::Crypto qw(btc_transaction);
+use Bitcoin::Crypto qw(btc_transaction btc_utxo);
 use Bitcoin::Crypto::PSBT::Map;
 use Bitcoin::Crypto::PSBT::Field;
 use Bitcoin::Crypto::PSBT::FieldType;
@@ -354,6 +354,41 @@ sub get_locktime
 	}
 }
 
+sub _get_utxo
+{
+	my ($self, $input_index, $txid, $output_index) = @_;
+
+	my $non_witness_utxo = $self->get_all_fields('PSBT_IN_NON_WITNESS_UTXO', $input_index);
+	my $witness_utxo = $self->get_all_fields('PSBT_IN_WITNESS_UTXO', $input_index);
+
+	return unless $non_witness_utxo || $witness_utxo;
+
+	my $output;
+
+	if ($non_witness_utxo) {
+		my $utxo_tx = $non_witness_utxo->value;
+
+		Bitcoin::Crypto::Exception::PSBT->raise(
+			'invalid PSBT_IN_NON_WITNESS_UTXO - txid mismatch'
+		) unless $utxo_tx->txid eq $txid;
+
+		Bitcoin::Crypto::Exception::PSBT->raise(
+			"invalid PSBT_IN_NON_WITNESS_UTXO - no output $output_index"
+		) unless defined $utxo_tx->outputs->[$output_index];
+
+		$output = $utxo_tx->outputs->[$output_index];
+	}
+	elsif ($witness_utxo) {
+		$output = $witness_utxo->value;
+	}
+
+	return btc_utxo->new(
+		txid => $txid,
+		output_index => $output_index,
+		output => $output,
+	);
+}
+
 sub get_transaction
 {
 	my ($self) = @_;
@@ -377,7 +412,10 @@ sub get_transaction
 			my $sequence_field = $self->get_all_fields('PSBT_IN_SEQUENCE', $input_index);
 
 			$tx->add_input(
-				utxo => [$utxo_txid, $utxo_output],
+
+				# try to get utxo - if not present in the PSBT, fallback to just
+				# basic UTXO information. UTXO will not be registered.
+				utxo => $self->_get_utxo($input_index, $utxo_txid, $utxo_output) // [$utxo_txid, $utxo_output],
 				(defined $sequence_field ? (sequence_no => $sequence_field->value) : ()),
 			);
 		}
@@ -595,6 +633,10 @@ L<Bitcoin::Crypto::Constants/LOCKTIME_HEIGHT_THRESHOLD>.
 
 Builds a new L<Bitcoin::Crypto::Transaction> object based on the contents of the PSBT.
 
+If UTXO fields in the PSBT are populated, then the resulting transaction inputs
+will have proper UTXOs set. However, those UTXOs will not be registered
+globally, and will only be available to this transaction only.
+
 =head3 to_serialized
 
 	$serialized = $object->to_serialized()

lib/Bitcoin/Crypto/Transaction/UTXO.pm

@@ -19,8 +19,6 @@ has param 'txid' => (
 	coerce => ByteStrLen [32],
 );
 
-# NOTE: ideally, utxo should point to a transaction, and transaction should
-# point to a block
 has option 'block' => (
 	isa => InstanceOf ['Bitcoin::Crypto::Block'],
 );

t/PSBT/integration.t

@@ -148,6 +148,53 @@ subtest 'should return valid height-based locktime from version 2 based on fallb
 	is $psbt->get_locktime, 555, 'locktime ok';
 };
 
+subtest 'should build transaction with UTXOs' => sub {
+	my $psbt = build_psbt(@minimal_v2);
+	ok !$psbt->get_transaction->inputs->[0]->utxo_registered, 'no utxo for base transaction ok';
+
+	$psbt = build_psbt(
+		@minimal_v2,
+		{
+			type => 'PSBT_IN_NON_WITNESS_UTXO',
+			index => 0,
+			raw_value => [
+				hex =>
+					'02000000000101511b7dac52f391e294e799b1b4097c1a60e578d5183e0d294de78638650b58500200000000ffffffff021a4f03000000000022512078b8bc45652bd8b48059d4d7cfa15415054dee17888ff42bd1dd97b778d0462443420100000000001600147e7467a4cde82b8681c927c30bc116f4916db16f02483045022100959c4a3a29b25df59c997764fff11aadc8e6889f3a58e3b87cab3807b92f00b5022045c7601bd902a70323e15ec4ba4dff57c1fc6e30475abc9f8cee6664190cf59d012102f6f1ff1fe9a1c43020f43b91d91d24090f0f803b54f8a32f17db2795a58949eb00000000'
+			],
+		}
+	);
+
+	is $psbt->get_transaction->inputs->[0]->utxo->output->locking_script->get_address,
+		'bc1p0zutc3t990vtfqze6ntulg25z5z5mmsh3z8lg273mktmw7xsgcjqrc42h3', 'non-witness utxo ok';
+
+	$psbt = build_psbt(
+		@minimal_v2,
+		{
+			type => 'PSBT_IN_WITNESS_UTXO',
+			index => 0,
+			raw_value =>
+				[hex => '1a4f03000000000022512078b8bc45652bd8b48059d4d7cfa15415054dee17888ff42bd1dd97b778d04624'],
+		}
+	);
+
+	is $psbt->get_transaction->inputs->[0]->utxo->output->locking_script->get_address,
+		'bc1p0zutc3t990vtfqze6ntulg25z5z5mmsh3z8lg273mktmw7xsgcjqrc42h3', 'witness utxo ok';
+};
+
+subtest 'should not build transaction with invalid non-witness UTXO' => sub {
+	my $psbt = build_psbt(
+		@minimal_v2,
+		{
+			type => 'PSBT_IN_NON_WITNESS_UTXO',
+			index => 0,
+			raw_value => [hex => $minimal_hex],
+		}
+	);
+
+	# feed tx to its own as its UTXO, which should fail (wrong transaction id)
+	isa_ok dies { $psbt->get_transaction }, 'Bitcoin::Crypto::Exception::PSBT';
+};
+
 done_testing;
 
 sub build_psbt