MeteorPlus/build.gradle.kts at 26.1.2 · MeteorClientPlus/MeteorPlus · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
plugins {
	alias(libs.plugins.fabric.loom)
	id("maven-publish")
}

base {
    archivesName = properties["archives_name"] as String
    version = libs.versions.mod.version.get()
    group = properties["maven_group"] as String
}

configurations.all {
	// Check for snapshots more frequently than Gradle's default of 1 day. 0 = every build.
	resolutionStrategy.cacheChangingModulesFor(0, "seconds")
}

repositories {
	// Modrinth
	maven {
		url = uri("https://api.modrinth.com/maven/")
		content {
			includeGroup("maven.modrinth")
		}
	}
	// Meteor Client
	maven {
        name = "meteor-maven"
        url = uri("https://maven.meteordev.org/releases")
    }
	maven {
        name = "meteor-maven-snapshots"
        url = uri("https://maven.meteordev.org/snapshots")
    }
	// XaeroLib
	maven {
		name = "Xaero's Maven"
		url = uri("https://chocolateminecraft.com/maven")
	}
	mavenCentral()
	gradlePluginPortal()
}

dependencies {
	// Fabric
	minecraft(libs.minecraft)
	implementation(libs.fabric.loader)

	// Fabric API
	implementation(libs.fabric.api)

	// Mixin extras
	annotationProcessor("io.github.llamalad7:mixinextras-fabric:0.5.4")

	// Meteor Client
	implementation(libs.baritone)
	implementation(libs.meteor.client)

	// Xaero's Mods
	compileOnly(libs.xlib) // XaeroLib
	compileOnly(libs.xwm) // Xaero's World Map
	compileOnly(libs.xmm) // Xaero's Minimap

	// Chest Tracker
	implementation(libs.whereisit)
}

java {
	toolchain {
		languageVersion.set(JavaLanguageVersion.of(libs.versions.jdk.get().toInt()))
	}
}

fun toMinecraftCompat(version: String): String {
	val match = Regex("""^(\d{2})\.([1-9]\d*)(?:\.([1-9]\d*))?$""")
		.matchEntire(version)
		?: error("Invalid Minecraft version format: $version. Expected YY.D or YY.D.H")

	val (year, drop, _) = match.destructured
	return "~$year.$drop"
}

loom {
	accessWidenerPath = file("src/main/resources/meteorplus.accesswidener")
}

tasks {
    processResources {
        val propertyMap = mapOf(
            "version" to project.version,
            "minecraft_version" to libs.versions.minecraft.get(),
			"jdk_version" to libs.versions.jdk.get(),
            "gh_hash" to (System.getenv("GITHUB_SHA") ?: ""),
        )

	    filesMatching("fabric.mod.json") {
		    expand (propertyMap)
        }
	}
    jar {
        val licenseSuffix = project.base.archivesName.get()
        from("LICENSE") {
            rename { "${it}_${licenseSuffix}" }
        }
    }
}