Erro ao tentar rodar o seguente código

[aquila0101]

tentei rodar na extenção e deu o seguinte erro:

programa
{
	inclua biblioteca Graficos --> g
	inclua biblioteca Matematica --> m

	funcao inicializar(){
		g.iniciar_modo_grafico(verdadeiro)
		g.definir_dimensoes_janela(1920, 1080)
	}

	funcao desenhar_cruz(inteiro x, inteiro y, inteiro tamanho ){
		inteiro largura = tamanho/5
		g.desenhar_retangulo(x-largura/2, y-tamanho/2, largura, tamanho, falso, verdadeiro)
		g.desenhar_retangulo(x-tamanho/2, y-largura/2, tamanho, largura, falso, verdadeiro)
	}

	funcao fractal(inteiro x, inteiro y, inteiro tamanho, inteiro profundidade){
		desenhar_cruz(x,y,tamanho)
		se(profundidade > 1){
			fractal(x+tamanho/2,y, tamanho/2, profundidade-1)
			fractal(x-tamanho/2,y, tamanho/2, profundidade-1)
			fractal(x,y+tamanho/2, tamanho/2, profundidade-1)
			fractal(x,y-tamanho/2, tamanho/2, profundidade-1)
			
		}
	}
	
	funcao inicio()	
	{
		inicializar()
		enquanto(verdadeiro){
			g.definir_cor(0x333333)
			g.limpar()
			g.definir_cor(0xeeeeee)
			fractal(1920/2,1080/2,1080/2,8)
			g.renderizar()
			
			
		}
	}
}

Originally posted by @AlissonSteffens in UNIVALI-LITE/Portugol-Studio#888

[leonelsanchesdasilva]

@aquila0101 Obrigado por reportar. Ainda não terminamos a implementação da biblioteca Graficos. Isso deve ocorrer mais futuramente.

Ticket relacionado: DesignLiquido/delegua-node#24

Vou manter essa issue aberta até termos a implementação, e então usarei este código como teste.